home *** CD-ROM | disk | FTP | other *** search
/ The PC-SIG Library 9 / The PC-SIG Library on CD ROM - Ninth Edition.iso / 001_100 / DISK0070 / DISK0070.ZIP / VPRINT.ASM < prev    next >
Assembly Source File  |  1983-02-13  |  8KB  |  230 lines
  1. ; PROGRAM VPRINT version 1.0
  2. ;      by Dave Whitman
  3. ;
  4. ; Redirects printer output to a specified disk file,
  5. ; providing a virtual printer.  Invoked from DOS by
  6. ; the command: VPRINT filespec
  7. ;
  8. ; Changes vector to BIOS printer routine to point
  9. ; to VPRINT code.  The VPRINT code is grafted onto
  10. ; DOS, and will not be overwritten by other programs.
  11. ;
  12. fcb            equ [5CH]   ;file control block
  13. name           equ [5DH]   ;name field of fcb
  14. name_length    equ 11      ;length of name field in fcb
  15. cur_block      equ [68H]   ;current block field
  16. current_rec    equ [7CH]   ;current record field
  17. record_size    equ [6AH]   ;record size field
  18. dta_length     equ 200H    ;length of internal disk buffer
  19. param_count    equ [80H]   ;contains # of chars in param area
  20. param_area     equ [81H]   ;PSP unformated param area
  21. dummy_dta      equ [80H]   ;leave dta set here on return
  22. cr             equ  0DH    ;ascii carriage return
  23. lf             equ  0AH    ;ascii line feed
  24. vector_offset  equ [005CH] ;offset part of interrupt vector 17H
  25. vector_segment equ [005EH] ;segment part of interrupt vector 17H
  26. printer_io     equ EFD2H   ;offset of BIOS routine
  27. ;
  28.        jmp init          ;branch around redirection code
  29. ;
  30. ;------------------------------------------------------
  31. ; This section of code will be grafted onto DOS.
  32. ; Calls to PRINTER_IO are redirected here, where
  33. ; they are converted to DOS sequential file writes.
  34. ; 
  35. convert 
  36.          sti                    ;enable interupts
  37.          or ah,ah               ;request to print char?
  38.          jnz abort              ;abort if not
  39. ;
  40.          push dx                ;save state
  41.          push ds 
  42.          push cs
  43.          pop  ds                ;and establish addr.
  44.          mov char,al            ;save the char
  45. ;
  46.          cmp al,lf             ;is this a line feed?
  47.          je  exit              ;exit if so
  48. ;
  49.          call printchar        ;print the charactor
  50.          cmp  al,cr            ;was that a carriage return?
  51.          jne  exit             ;exit if not
  52.          mov al,lf             ;otherwise generate a line feed
  53.          call printchar        ;and send it
  54. ;
  55. exit     mov al,char           ;restore state
  56.          pop ds
  57.          pop dx
  58. ;
  59. ;=========================================================
  60. ; We have to return a status byte in AH.  The way I read
  61. ; Tech. Ref., to signal all ok we should send value 50H.
  62. ; However, a long DEBUG session showed that Easywriter 1.1
  63. ; expects to get 90H as the OK value.  I would interpret this
  64. ; as "printer busy", but we'll humor Easywriter.  
  65. ;=========================================================
  66. ;
  67. abort    mov ah,90H            ;move status = ok to AH
  68.          iret                  ;and return
  69. ;
  70. printchar proc near
  71.           push di
  72.           mov di,numchars      ;position in buffer for char
  73.  
  74.           mov offset(dta)[di],al ;mov char into buffer
  75. ;
  76.           inc di               ;update number of chars
  77.           mov numchars,di      ;and save it
  78. ;
  79.           cmp di,dta_length    ;is the buffer full?
  80.           jne pc-exit          ;exit if not
  81.           call dumpdta         ;otherwise dump it
  82. ;
  83. pc-exit   pop di
  84.           ret
  85.           endp
  86. ;
  87. dumpdta  proc near
  88.          push ax                       ;save state
  89.          push dx
  90. ;
  91.          mov ah,0FH                    ;open file
  92.          mov dx,offset(fcb)
  93.          int 21H
  94. ;
  95.          movw record_size,dta_length   ;set record size
  96.  
  97.          mov  ax,block_save            ;set fcb current block
  98.          mov  cur_block,ax
  99. ;
  100.          mov dx,offset(dta)            ;set disk transfer addr.
  101.          mov ah,1AH
  102.          int 21H
  103. ;
  104.          mov dx, offset(fcb)           ;write buffer to disk
  105.          mov ah,15H
  106.          int 21H
  107. ;
  108.          mov  ax, cur_block            ;save current block
  109.          mov  block_save,ax
  110. ;
  111.          mov  ax,1000H                 ;close file
  112.          mov  dx,offset(fcb)
  113.          int  21H
  114. ;
  115.          movw numchars,0000H           ;buffer is now empty
  116. ;
  117. ;======================================================
  118. ; Since we don't know where the DTA was set upon entry,
  119. ; we can't really restore the state of the machine.
  120. ; What we'll do is set up a dummy DTA for the caller to
  121. ; use, so it doesn't clobber our buffered data between calls.
  122. ; This is *NOT* foolproof, but seems to work OK with Easywriter.
  123. ;======================================================
  124. ;
  125.          mov dx,offset(dummy_dta)   ;set DTA to dummy block
  126.          mov ah,1AH
  127.          int 21H
  128.  
  129.          pop dx                     ;restore state
  130.          pop ax
  131.          ret                        ;and return
  132.          endp
  133. ;
  134. ;====================================================
  135. ; Data area for resident section
  136. ;====================================================
  137. char       db 00H           ;to save the char. passed
  138. numchars   db 00H,00H       ;word: # of chars in buffer
  139. block_save db 00H,00H       ;to save current block between calls
  140. dta        ds dta_length    ;internal data buffer
  141. ;
  142. ;===================================================
  143. ; Initialization section.  Does not become resident.
  144. ;===================================================
  145. init   cmpb name,' '              ;was a file specified?
  146.        jnz  a1                    ;skip if so
  147.  
  148.        cmpb param_count,00H       ;any param chars?
  149.        jz   default               ;skip if not
  150.        xor  ch,ch                 ;set up for scan
  151.        mov  cl,param_count
  152.        mov  di,offset(param_area)
  153.        mov  al,'/'                ;look for '/'
  154.        repnz                      ;scan to end or 1st match
  155.        scasb
  156. ;
  157.        jnz default                ;skip if not found
  158.        xorb [di],20H              ;guarantees upper case
  159. ;
  160.        cmpb [di],'N'              ;is it an N?
  161.        je   p_handler             ;if so, jump
  162. ;
  163. ;if no parameters decoded, just fall through
  164. ;and set up print file with default name
  165. ;
  166. default mov  si, offset(default_file_name)
  167.         mov  di, offset(name)
  168.         mov  cx, name_length
  169.         rep
  170.         movsb
  171. ;
  172. a1     mov dx, offset(fcb)         ;check if file exists
  173.        mov ah,11H
  174.        int 21H
  175. ;
  176.        test al,al                  ;file found?
  177.        jnz  a2                     ;skip if not
  178. ;
  179.        mov  dx, offset(err_msg_1)  ;otherwise print
  180.        mov  ah,09H                 ;error message
  181.        int 21H
  182.        int 20H                     ;and return to DOS
  183. ;
  184. a2     mov ah,16H                  ;create file
  185.        int 21H
  186. ;
  187.        test al,al                  ;file created?
  188.        jz   a3                     ;skip if so
  189.        mov  dx, offset(err_msg_2)  ;otherwise error
  190.        mov  ah, 09H
  191.        int  21H
  192.        int  20H
  193. ;
  194. a3     movw current_rec, 0         ;fill in fcb
  195. ;
  196.        mov ah,10H                  ;close file
  197.        mov dx, offset(fcb)
  198.        int 21H
  199. ;
  200.        mov ax,2517H                ;reset printer vector
  201.        mov dx, offset(convert)
  202.        int 21H
  203. ;
  204.        mov dx,offset(init)         ;point dx past resident code
  205.        int 27H                     ;end but stay resident
  206. ;===================================================================
  207. p_handler
  208. ;
  209.        mov ax,0000H              ;ext. addr. for vector
  210.        mov ds,ax
  211. ;
  212.        cmpw vector_offset,printer_io  ;already in BIOS?
  213.        je   p_exit                    ;exit if so
  214. ;
  215.        mov  ds,vector_segment    ;est. addr. in original vprint seg
  216.        call dumpdta              ;operates on buffer in original vprint
  217. ;
  218.        mov  ax,F000H             ;reset vector 17H to BIOS routine
  219.        mov  ds,ax                ;bios segment
  220.        mov  dx,printer_io        ;printer support routine
  221.        mov  ax,2517H
  222.        int 21H 
  223. ;
  224. p_exit int  20H                  ;return to DOS
  225. ;
  226. ;===================================================================
  227. err_msg_1  db 'File already exists!$'
  228. err_msg_2  db 'No room for file in directory.$'
  229. default_file_name db 'VIRTUAL PRN'
  230.